Semester Final Project — A desk drawer with hidden compartment

Background

*Intuitively, many would argue that an "alert" system could be entirely achieved by simply installing a camera in the room. While this may be true, I believe many share the experience of spotting something off about a friend and choosing not to bring it up, to avoid awkwardness. This is similar. By implementing a subtle, less noticeable approach, I spare both the culprit and myself from that discomfort.

Also, even though it is an incredible simple device, it is the culmination of this semester's study. I had the skills needed summarized below:

In the past weeks, I have gradually prepared the parts needed for this project. At this moment I have:

To make the system more integrated and just generally...better looking, I also designed a case that would protec the board/chip

Next onto the email alert system part. Since the microcontroller I'm using, ESP32S3, has its own wifi module, it is very convenient to implement network feature. I googled a bit and decided to implement the email feature via a site called IFTTT

IFTTT stands for "If this then that." It is a web-based service that allows users to create chains of simple conditional statements, called applets, which are triggered based on changes to other web services such as Gmail, Facebook, Instagram, or Pinterest. In my case, I set up an applet that sends me an email whenever it receives a web request with a specific event name.

Unfortunately, the board alone worked perfectly when I tested it separately, but once I put it in the case, it stopped working! This was 1:00am in the morning ON THE DAY of the demo. My theory is when I paste the board to the case I accidentally damaged part of the circuit. Accordingly to the serial monitor, the networking function works fine, but the program after that cannot be triggered as the distance sensor cannot be found.(Even though it is obviously still connected.)

I tried to find out what went wrong with multimeter, no obvious reason was found. To avoid wasting more time on something that I'm not sure I can find quickly, I quickly gathered some new parts and made another one. It is such a good thing I still have the original code that I used for the setup (BTW, I did not know once the code was uploaded as a sketch, one cannot really retrieve the original code from the microcontroller)

One feature I tried and worked in the test but did not work after I tried to implement is the RFID card. I had the idea of using the RFID card I got from Anthony as some kind of remote trigger. By using a card, I don't have to lift the panel everytime I want to turn it on or activate it. Ideally it would work when there's something in between. However, it turned out the OSB I used may be too thick for it to work in a stable way. The chance of getting the reader successfully sense the card when there's a board in between is about 50% at any random try. So I abandoned this feature as well.

Code I used in Arduino:

  #include <WiFi.h>
  #include <WiFiClientSecure.h>
  #include <HTTPClient.h>
  #include <Wire.h>
  #include <VL53L1X.h>

  // ===================== WIFI + IFTTT =====================
  const char* WIFI_SSID     = "Tony";
  const char* WIFI_PASSWORD = "11111111";

  const char* IFTTT_EVENT = "esp32_alert";
  const char* IFTTT_KEY   = "d8IgdE57WlH1lydsa_jZ_E";
  // =======================================================

  // ===================== SENSOR / TRIGGER LOGIC ===========
  const uint16_t THRESHOLD_MM = 200;     // trigger when < 200 mm
  const uint16_t REARM_MM     = 260;     // must rise above this to re-arm
  const uint32_t COOLDOWN_MS  = 60000;   // 1 minute
  // =======================================================

  VL53L1X sensor;

  uint32_t lastTriggerMs = 0;
  bool armed = true;

  String iftttUrl() {
    return "https://maker.ifttt.com/trigger/" + String(IFTTT_EVENT) +
           "/with/key/" + String(IFTTT_KEY);
  }

  bool triggerIFTTT(uint16_t distanceMm) {
    WiFiClientSecure client;
    client.setInsecure(); // fine for testing

    HTTPClient https;
    if (!https.begin(client, iftttUrl())) {
      Serial.println("HTTPS begin() failed");
      return false;
    }

    https.addHeader("Content-Type", "application/json");

    String payload =
      String("{") +
      "\"value1\":\"ESP32-S3 + VL53L1X\"," +
      "\"value2\":\"Distance threshold crossed\"," +
      "\"value3\":\"Distance=" + String(distanceMm) + "mm\"" +
      "}";

    int code = https.POST(payload);

    Serial.print("IFTTT HTTP code: ");
    Serial.println(code);
    Serial.println(https.getString());

    https.end();
    return (code > 0 && code < 400);
  }

  void connectWiFi() {
    WiFi.mode(WIFI_STA);
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

    Serial.print("Connecting WiFi");
    uint32_t start = millis();
    while (WiFi.status() != WL_CONNECTED) {
      delay(300);
      Serial.print(".");
      if (millis() - start > 20000) ESP.restart();
    }
    Serial.println("\nWiFi connected");
  }

  void setupSensor() {
    Wire.begin();          // no explicit pin numbers
    delay(50);

    sensor.setTimeout(500);

    if (!sensor.init()) {
      Serial.println("VL53L1X not detected (check wiring & power)");
      while (true) delay(1000);
    }

    sensor.setDistanceMode(VL53L1X::Long);
    sensor.setMeasurementTimingBudget(50000);
    sensor.startContinuous(50);

    Serial.println("VL53L1X initialized");
  }

  void setup() {
    Serial.begin(115200);
    delay(300);

    connectWiFi();
    setupSensor();

    Serial.println("Monitoring distance…");
  }

  void loop() {
    uint16_t d = sensor.read();

    if (sensor.timeoutOccurred()) {
      Serial.println("VL53L1X timeout");
      delay(50);
      return;
    }

    Serial.print("Distance (mm): ");
    Serial.println(d);

    if (!armed && d > REARM_MM) {
      armed = true;
      Serial.println("Re-armed");
    }

    uint32_t now = millis();
    bool cooldownOk = (now - lastTriggerMs) >= COOLDOWN_MS;

    if (armed && cooldownOk && d > 0 && d < THRESHOLD_MM) {
      Serial.println("** ALERT: threshold crossed **");
      if (triggerIFTTT(d)) {
        lastTriggerMs = now;
        armed = false;
      }
    }

    delay(100);
  }
    

Some Afterthoughts:

At the beginning of this project, I had two concerns: 1. Can this thing work in the dark, and 2. How long can a battery powered device last, given the sustained period of working hour it needs.

Answer for the first question: All the VL53 series distance sensors work perfectly in complete darkness as they use their own active infrared laser emitter(around 940nm). These sensors do not rely on visible light at all, they measure time-of-flight, the timing of the reflected infrared pulse, not brightness.One note is that a strong sunlight may interfere with the sensor, but since I'm going to place it in a drawer, in a normal bedroom condition, it should be fine.

For my second concern, since it needs to constantly emit IR to be working. I was worried it may be very power hungry if I were to power the sensor with just a triple A battery. Based on the information I gathered, i did a bit of math, this is the answer: